1 PRINT"[147]":POKE53280,0:POKE53281,6:POKE646,1
2 REM       "SHOTGUN LOADER"
4 REM      BY R. HAROLD DROID
10 IFSG=1THEN30
20 SG=1:LOAD"SHOTGUN SHELL",8,1
30 PRINTCHR$(13)"THIS PROGRAM CREATES AN AUTO-MENU"
33 PRINT"  FOR A GIVEN DISK"CHR$(13)
34 PRINT"SYS51200 ENABLES YOUR NEW PROGRAM:"
35 PRINT" SHIFT/RESTORE BREAKS TO MENU"
36 PRINT" SPACE/RESTORE RERUNS WITHOUT RELOADING"
37 PRINT" RUN-STOP/RESTORE DISABLES"
38 PRINT" COMMODORE/RESTORE DOES NON-DISABLING"
39 PRINT"   WARM START"CHR$(13)
40 PRINT"INSERT A DISK CONTAINING"
50 PRINT"  BASIC PROGRAM FILES"
60 PRINT"  THEN PRESS A KEY"CHR$(13)
70 POKE198,0:WAIT198,1
80 REM ******* READ DIRECTORY ********
85 PN=1:PT=51769
90 OPEN1,8,0,"$0"
100 FLAG=1:REM FLAG SET FOR READING DISK NAME
110 F$="":GET#1,B$,B$,B$,B$
120 GET#1,B$:IF ST<>0 THEN320
130 IF B$<>CHR$(34) THEN120
140 GET#1,B$:IF B$<>CHR$(34)THEN F$=F$+B$:GOTO140
150 GET#1,B$:IF B$=CHR$(32) THEN150
160 GET#1,B$:IFB$<>""THEN160
170 IF ST<>0 THEN320
180 IFFLAG=0THEN230
190 FLAG=0:DN$(DN)=F$:PRINT"DISK NAME: "DN$(DN)CHR$(13)
200 PRINT"INDICATE WHETHER A FILE SHOULD"
210 PRINT"  BE INCLUDED IN THE AUTO-MENU"
215 PRINT"  BY PRESSING Y OR N"
218 PRINT"  CAPACITY IS 26 FILES!"CHR$(13)
220 GOTO110
230 PRINTF$;
240 POKE198,0:WAIT198,1:GETA$:IFA$="Y"THEN270
250 IFA$="N"THENPOKE211,0:PRINT"                ";:POKE211,0:GOTO110
260 GOTO240
270 PRINT
275 IFLEN(F$)<>16THENF$=F$+CHR$(160):GOTO275
280 FORA=1TO16:POKEPT,ASC(MID$(F$,A,1)):PT=PT+1:NEXT
290 PN=PN+1:IFPN>27THEN400
310 GOTO110
320 CLOSE1:POKE51768,PN:PT=PT+1
322 PRINT:INPUT"AUTO MENU FILENAME  SHOTGUN[157][157][157][157][157][157][157][157][157]";PG$
330 OPEN8,8,8,PG$+",P,W"
340 PRINT#8,CHR$(0);:PRINT#8,CHR$(192);
350 FORA=51200TOPT:PRINT#8,CHR$(PEEK(A));:NEXT
360 CLOSE8:END
400 PRINT"MENU CAPACITY EXCEEDED!  TRY AGAIN...":CLOSE1:GOTO85